Latest post Tue, May 6 2008 10:15 PM by Gordon Fontenot. 2 replies.
Page 1 of 1 (3 items)
Sort Posts: Previous Next
  • Fri, Jul 27 2007 3:46 PM

    • mark.burton
    • Top 150 Contributor
    • Joined on Thu, Oct 13 2005
    • London, UK
    • Posts 929
    • Points 11,325

    Send an SMS when your Render / Export / Mixdown is done

    Most applications have a timer to indicate roughly how long a process will take, but although they do a good job, often they are not that accurate or effects later in a sequence can significantly change this estimate later on. One way to know for sure your system is free to use again is for it to tell you so, even when you're out of the room, or the building, perhaps in the pub next door!

    My friend Andreas Kiel wrote an Applescript for Final Cut Pro which sets off a sequence render, monitors its progress and then sends an SMS using Skype when the render is complete!!

    I wondered if we could get it working for Xpress Pro as well and he made some nifty changes to do just that. Here is the Applescript for anyone who wants it. Just copy the script text into the 'Script Editor' program which comes with Mac OS X and change the phone number (+xxxxxxxxxxxx) to your own mobile /cell number with the international dialing code at the front. For example a UK mobile number needs +44 at the front, a US one would need +1 etc.

    This is all you need:
    - Latest version of Skype installed. (It must be running and online when you run the script)
    - Some SkypeOut credit to send the SMS.
    - Make sure Enable access for assistive devices is ticked in System Prefs > Universal Access.
    - Make sure All Controls is ticked at the bottom of System Prefs > Keyboard & Mouse > Keyboard shortcuts.

    The way it works:
    1. Start you render / export / mixdown going in Xpress Pro
    2. Run the script
    3. Go and relax

    (Once you have entered your phone number you could save this script as an application and put it in the dock for easy access - set the app to Run Only.)

    -----------------------------------------------------------------------------------------------------------------------------------------------------------

    my watchAVID()
    my sendSkypeCall("+xxxxxxxxxxxx", "Your Avid render is done")


    on watchAVID()
        tell application "System Events"
            tell application process "AvidXpressPro"
                
                repeat
                    set windowList1 to {} -- just to make sure its reset
                    try
                        with timeout of 5 seconds -- stop asking after 5 seconds
                            set windowList1 to get name of every window
                        end timeout
                    on error
                        set windowList1 to {}
                    end try
                   
                   
                    if windowList1 ≠ {} and windowList1 does not contain "Thermometer" then
                        exit repeat
                    end if
                   
                    delay 10 -- wait 10 seconds before trying again
                end repeat
               
            end tell
        end tell
    end watchAVID


    on sendSkypeCall(internationalPhoneNumber, theText)
        tell application "Skype"
            activate
        end tell
       
        tell application "System Events"
            tell application process "Skype"
                set theTarget to "skype:" & internationalPhoneNumber & "?sms"
                open location theTarget
               
                keystroke theText
                delay 2
               
                keystroke tab using shift
                keystroke return
               
            end tell
        end tell
    end sendSkypeCall


    -----------------------------------------------------------------------------------------------------------------------------------------------------------

  • Fri, Jul 27 2007 4:09 PM In reply to

    Re: Send an SMS when your Render / Export / Mixdown is done

    I'll definitely try this out... I love SMS notifications.

    Updating:  I just tried it..works great.  

    NOTE to MC users... change "AvidXpressPro" to "AvidMediaComposer"



    Kenton VanNatten | Avid Editor (for hire)

    "I am not obsessed... I'm detail-oriented"

  • Tue, May 6 2008 10:15 PM In reply to

    Re: Send an SMS when your Render / Export / Mixdown is done

    Just found this, and I'm in love.  But I'm not sure if something has changed in skype since this was written, because it wasn't sending the SMS out, only writing it.  I'm assuming that since this script was written, Skype began allowing multi-lined SMS'.  The return command in the script only drops down a line.  I added the keystroke command keystroke to get this to work.  Here it is.

     

     

    my watchAVID()

    my sendSkypeCall("+xxxxxxxxxxx", "Avid Render Complete")

     

     

    on watchAVID()

    tell application "System Events"

    tell application process "AvidMediaComposer"

    repeat

    set windowList1 to {} -- just to make sure its reset

    try

    with timeout of 5 seconds -- stop asking after 5 seconds

    set windowList1 to get name of every window

    end timeout

    on error

    set windowList1 to {}

    end try

    if windowList1 ≠ {} and windowList1 does not contain "Thermometer" then

    exit repeat

    end if

    delay 10 -- wait 10 seconds before trying again

    end repeat

    end tell

    end tell

    end watchAVID

     

     

    on sendSkypeCall(internationalPhoneNumber, theText)

    tell application "Skype"

    activate

    end tell

    tell application "System Events"

    tell application process "Skype"

    set theTarget to "skype:" & internationalPhoneNumber & "?sms"

    open location theTarget

    keystroke theText

    delay 2

    keystroke tab using shift

                            key down command

    keystroke return

                            key up command

    end tell

    end tell

    end sendSkypeCall

     

     

    --EDIT--

    Just realized that with the tab key setting laid out in the first paragraph (that I forgot to do), you don't need those extra 2 lines.  My way works, and that "keystroke tab using shift" is probably superfluous in my copy.  But if you don't want to change that setting (I like tab only changing to my text boxes) mine will work.

     

Page 1 of 1 (3 items)

© Copyright 2011 Avid Technology, Inc.  Terms of Use |  Privacy Policy |  Site Map |  Find a Reseller